nur-packages

commit e2895ad72eedc7a7578a90c3261c80f98482bde4
parent 2acdf32d456e2d3df8a0e169de68559895e2a447
Author: Nikolay Korotkiy <sikmir@disroot.org>
Date:   Mon,  9 Feb 2026 23:00:52 +0400

Add overpass-turbo

Diffstat:
A
pkgs/by-name/ov/overpass-turbo/package.nix
 | 
58
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

1 file changed, 58 insertions(+), 0 deletions(-)
diff --git a/pkgs/by-name/ov/overpass-turbo/package.nix b/pkgs/by-name/ov/overpass-turbo/package.nix
@@ -0,0 +1,58 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchPnpmDeps,
+  nodejs,
+  pnpm,
+  pnpmConfigHook,
+  writableTmpDirAsHomeHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "overpass-turbo";
+  version = "2026-01-28";
+
+  src = fetchFromGitHub {
+    owner = "tyrasd";
+    repo = "overpass-turbo";
+    rev = "644c5ec33864d3acadf25b5b7d3e6ad876d09c0d";
+    hash = "sha256-HvCarTfqL33wYlrY6S+tqyc7d4fYqkYgw0P7X/bgTqQ=";
+  };
+
+  postPatch = ''
+    substituteInPlace vite.config.mts \
+      --replace-fail "git log -1 --format=%cd --date=short" "echo ${finalAttrs.version}" \
+      --replace-fail "git describe --always" "echo ${finalAttrs.src.rev}"
+  '';
+
+  pnpmDeps = fetchPnpmDeps {
+    inherit (finalAttrs) pname version src;
+    fetcherVersion = 3;
+    hash = "sha256-S3MkYiQQUiztdFhfDkoPrI8c77VNx4AQVq0MPrCuqF4=";
+  };
+
+  nativeBuildInputs = [
+    nodejs
+    pnpm
+    pnpmConfigHook
+    writableTmpDirAsHomeHook
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+    pnpm build
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    mv dist $out
+  '';
+
+  meta = {
+    description = "A web based data mining tool for OpenStreetMap using the Overpass API";
+    homepage = "https://github.com/tyrasd/overpass-turbo";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.sikmir ];
+  };
+})