nur-packages

commit 4943e8d9c4a90ddbee87295899d94da568fca191
parent 629cb862e7107401711f85f2c5cd2c441e8d423f
Author: Nikolay Korotkiy <sikmir@disroot.org>
Date:   Thu,  5 Jun 2025 21:13:46 +0400

Add msg-cli

Diffstat:
M
pkgs/default.nix
 | 
1
+
A
pkgs/misc/msg-cli/default.nix
 | 
52
++++++++++++++++++++++++++++++++++++++++++++++++++++

2 files changed, 53 insertions(+), 0 deletions(-)
diff --git a/pkgs/default.nix b/pkgs/default.nix
@@ -376,6 +376,7 @@ lib.makeScope newScope (
     modbus-tools = callPackage ./misc/modbus-tools { };
     modbus_sim_cli = callPackage ./misc/modbus_sim_cli { python3Packages = pkgs.python310Packages; };
     morse-talk = callPackage ./misc/morse-talk { python3Packages = pkgs.python311Packages; };
+    msg-cli = callPackage ./misc/msg-cli { };
     musig = callPackage ./misc/musig { };
     mysql-to-sqlite3 = callPackage ./misc/mysql-to-sqlite3 { };
     nanodns = callPackage ./misc/nanodns { };
diff --git a/pkgs/misc/msg-cli/default.nix b/pkgs/misc/msg-cli/default.nix
@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  autoreconfHook,
+  pkg-config,
+  texinfo,
+  makeWrapper,
+  guile,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "msg-cli";
+  version = "0.1.1";
+
+  src = fetchFromGitea {
+    domain = "forge.superkamiguru.org";
+    owner = "MSG";
+    repo = "msg-cli";
+    tag = "v${version}";
+    hash = "sha256-M/MksKwmV/PQxRtv9cT3KwMquhu2yUyBI9+jQL/vsfA=";
+  };
+
+  postPatch = ''
+    substituteInPlace msg/machine.scm \
+      --replace-fail "/opt/homebrew/bin/" "" \
+      --replace-fail "/usr/local/bin/" ""
+  '';
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    texinfo # For makeinfo
+    makeWrapper
+  ];
+
+  buildInputs = [ guile ];
+
+  postInstall = ''
+    wrapProgram $out/bin/msg \
+      --prefix GUILE_LOAD_PATH : "$out/${guile.siteDir}:$GUILE_LOAD_PATH" \
+      --prefix GUILE_LOAD_COMPILED_PATH : "$out/${guile.siteCcacheDir}:$GUILE_LOAD_COMPILED_PATH"
+  '';
+
+  meta = {
+    description = "MacOS Subsystem for Guix";
+    homepage = "https://forge.superkamiguru.org/MSG/msg-cli";
+    license = lib.licenses.agpl3Only;
+    maintainers = [ lib.maintainers.sikmir ];
+    mainProgram = "msg";
+  };
+}