nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (1384B)

      1 { lib, fetchFromGitHub, python3Packages, s2sphere }:
      2 
      3 python3Packages.buildPythonApplication rec {
      4   pname = "gpxtrackposter";
      5   version = "2021-04-01";
      6 
      7   src = fetchFromGitHub {
      8     owner = "flopp";
      9     repo = pname;
     10     rev = "545c551b808fece43ff199e006d8a1c399536a05";
     11     hash = "sha256-2if0e74mYItTM7tYc2OS2EhZu3gnZjfkT5kzLnacH7Y=";
     12   };
     13 
     14   patches = [ ./fix-localedir.patch ];
     15 
     16   postPatch = ''
     17     substituteInPlace gpxtrackposter/poster.py \
     18       --replace "self.translate(\"ATHLETE\")" "\"\""
     19     substituteInPlace gpxtrackposter/cli.py \
     20       --subst-var out
     21   '';
     22 
     23   propagatedBuildInputs = with python3Packages; [
     24     appdirs
     25     dateutil
     26     gpxpy
     27     svgwrite
     28     colour
     29     s2sphere
     30     pint
     31     polyline
     32     pytz
     33     setuptools
     34     stravalib
     35     timezonefinder
     36   ];
     37 
     38   checkInputs = with python3Packages; [
     39     pytestCheckHook
     40     (pytest-mock.overrideAttrs (old: rec {
     41       pname = "pytest-mock";
     42       version = "3.3.1";
     43       src = fetchPypi {
     44         inherit pname version;
     45         sha256 = "10mv262aq0y70g7q9689vkalaayx73l8kylzgpkr7a7455rx7mm4";
     46       };
     47     }))
     48   ];
     49 
     50   postInstall = "rm -fr $out/requirements*.txt";
     51 
     52   meta = with lib; {
     53     description = "Create a visually appealing poster from your GPX tracks";
     54     inherit (src.meta) homepage;
     55     license = licenses.mit;
     56     maintainers = [ maintainers.sikmir ];
     57     platforms = platforms.unix;
     58   };
     59 }