nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (1162B)


      1 { lib, stdenv, fetchFromGitHub, fetchpatch, cmake, boost, catch2_3, libcpr, trompeloeil }:
      2 
      3 stdenv.mkDerivation (finalAttrs: {
      4   pname = "influxdb-cxx";
      5   version = "0.7.2";
      6 
      7   src = fetchFromGitHub {
      8     owner = "offa";
      9     repo = "influxdb-cxx";
     10     rev = "v${finalAttrs.version}";
     11     hash = "sha256-DFslPrbgqS3JGx62oWlsC+AN5J2CsFjGcDaDRCadw7E=";
     12   };
     13 
     14   patches = [
     15     # Fix unclosed test case tag
     16     (fetchpatch {
     17       url = "https://github.com/offa/influxdb-cxx/commit/b31f94982fd1d50e89ce04f66c694bec108bf470.patch";
     18       hash = "sha256-oSdpNlWV744VpzfiWzp0ziNKaReLTlyfJ+SF2qyH+TU=";
     19     })
     20   ];
     21 
     22   nativeBuildInputs = [ cmake ];
     23 
     24   buildInputs = [ boost libcpr ]
     25     ++ lib.optionals finalAttrs.doCheck [ catch2_3 trompeloeil ];
     26 
     27   cmakeFlags = [
     28     (lib.cmakeBool "INFLUXCXX_TESTING" finalAttrs.doCheck)
     29     (lib.cmakeFeature "CMAKE_CTEST_ARGUMENTS" "-E;BoostSupportTest") # requires network access
     30   ];
     31 
     32   doCheck = true;
     33 
     34   meta = with lib; {
     35     description = "InfluxDB C++ client library";
     36     inherit (finalAttrs.src.meta) homepage;
     37     license = licenses.mit;
     38     maintainers = [ maintainers.sikmir ];
     39     platforms = platforms.unix;
     40   };
     41 })