nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (1082B)

      1 { lib, stdenv, fetchFromGitHub, cmake, ghc_filesystem, glfw, libglvnd, libGLU }:
      2 
      3 stdenv.mkDerivation (finalAttrs: {
      4   pname = "objlab";
      5   version = "0-unstable-2019-11-23";
      6 
      7   src = fetchFromGitHub {
      8     owner = "lighttransport";
      9     repo = "objlab";
     10     rev = "c9d50b466f477722578ddf14565561d778c1b4b9";
     11     hash = "sha256-mE4s+viW6fGfnd8+LlDH4LyRLQ91nwe9dtxyI+dIhsM=";
     12   };
     13 
     14   postPatch = ''
     15     substituteInPlace CMakeLists.txt \
     16       --replace-fail "add_subdirectory" "#add_subdirectory"
     17   '';
     18 
     19   nativeBuildInputs = [ cmake ];
     20 
     21   buildInputs = [
     22     ghc_filesystem
     23     glfw
     24     libglvnd
     25     libGLU
     26   ];
     27 
     28   env.NIX_CFLAGS_COMPILE = "-fpermissive";
     29 
     30   cmakeFlags = [
     31     (lib.cmakeFeature "OpenGL_GL_PREFERENCE" "GLVND")
     32   ];
     33 
     34   installPhase = ''
     35     install -Dm755 objlab -t $out/bin
     36   '';
     37 
     38   meta = with lib; {
     39     description = "Simple wavefront .obj viewer";
     40     inherit (finalAttrs.src.meta) homepage;
     41     license = licenses.mit;
     42     maintainers = [ maintainers.sikmir ];
     43     platforms = platforms.linux;
     44     skip.ci = stdenv.isDarwin;
     45     mainProgram = "objlab";
     46   };
     47 })