nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (1142B)

      1 {
      2   lib,
      3   python3Packages,
      4   fetchFromGitHub,
      5   withCli ? true,
      6   checkLang ? false,
      7 }:
      8 
      9 python3Packages.buildPythonApplication rec {
     10   pname = "tatoebatools";
     11   version = "0.2.3";
     12 
     13   src = fetchFromGitHub {
     14     owner = "LBeaudoux";
     15     repo = "tatoebatools";
     16     rev = "v${version}";
     17     hash = "sha256-45CDAH80z6zApgR4gK7ZLPSXtCyPx+6YaA61Iskued4=";
     18   };
     19 
     20   patches =
     21     lib.optional (!checkLang) ./dont-check-lang-validity.patch
     22     ++ lib.optional withCli ./cli.patch;
     23 
     24   dependencies =
     25     with python3Packages;
     26     [
     27       beautifulsoup4
     28       pandas
     29       requests
     30       sqlalchemy
     31       setuptools
     32       tqdm
     33     ]
     34     ++ lib.optionals withCli [
     35       click
     36       xdg-base-dirs
     37     ];
     38 
     39   nativeCheckInputs = with python3Packages; [ pytestCheckHook ];
     40 
     41   disabledTests = lib.optionals (!checkLang) [
     42     "test_init_with_not_language_1"
     43     "test_init_with_not_language_2"
     44   ];
     45 
     46   meta = {
     47     description = "A library for downloading, updating and iterating over data files from Tatoeba";
     48     homepage = "https://github.com/LBeaudoux/tatoebatools";
     49     license = lib.licenses.mit;
     50     maintainers = [ lib.maintainers.sikmir ];
     51   };
     52 }