nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (1284B)

      1 { lib
      2 , stdenv
      3 , fetchurl
      4 , autoconf
      5 , automake
      6 , libtool
      7 , p7zip
      8 , pkg-config
      9 , gtk2
     10 , libmysqlclient
     11 , libxml2
     12 , pcre
     13 }:
     14 
     15 stdenv.mkDerivation (finalAttrs: {
     16   pname = "stardict-tools";
     17   version = "3.0.6";
     18 
     19   src = fetchurl {
     20     url = "mirror://sourceforge/stardict-4/stardict-${finalAttrs.version}-2-src.7z";
     21     hash = "sha256-2Q+PNqFCnxioFmD4IEUQlD2x22Ueh+nKXP5i9N3STFE=";
     22   };
     23 
     24   nativeBuildInputs = [
     25     autoconf
     26     automake
     27     libtool
     28     p7zip
     29     pkg-config
     30   ];
     31 
     32   buildInputs = [
     33     gtk2
     34     libmysqlclient
     35     libxml2
     36     pcre
     37   ];
     38 
     39   hardeningDisable = [ "format" ];
     40 
     41   postPatch = ''
     42     substituteInPlace tools/src/Makefile.am \
     43       --replace-fail "noinst_PROGRAMS =" "bin_PROGRAMS ="
     44   '';
     45 
     46   preConfigure = "./autogen.sh";
     47   configureFlags = [
     48     (lib.enableFeature false "dict")
     49   ];
     50 
     51   env.NIX_CFLAGS_COMPILE = "-std=c++14";
     52 
     53   postInstall = ''
     54     find $out/bin/ -not -name 'stardict-*' -type f | \
     55       sed 'p;s#bin/#bin/stardict-#' | \
     56       xargs -n2 mv
     57   '';
     58 
     59   enableParallelBuilding = true;
     60 
     61   meta = with lib; {
     62     description = "Stardict tools";
     63     homepage = "https://stardict-4.sourceforge.net/";
     64     license = licenses.gpl3Plus;
     65     maintainers = [ maintainers.sikmir ];
     66     platforms = platforms.unix;
     67     broken = stdenv.isDarwin;
     68   };
     69 })