nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (934B)

      1 {
      2   lib,
      3   fetchFromGitHub,
      4   python3Packages,
      5   withUI ? true,
      6 }:
      7 
      8 python3Packages.buildPythonApplication rec {
      9   pname = "gt4gd";
     10   version = "1.3.9";
     11   pyproject = true;
     12 
     13   src = fetchFromGitHub {
     14     owner = "xinebf";
     15     repo = "google-translate-for-goldendict";
     16     tag = "v${version}";
     17     hash = "sha256-zJq5dhmrd0k7bsw75xFECKmwZU4qjw+wwSzsYjg8zao=";
     18   };
     19 
     20   build-system = with python3Packages; [ setuptools ];
     21 
     22   dependencies = with python3Packages; [ requests ] ++ lib.optional withUI tkinter;
     23 
     24   doCheck = false;
     25 
     26   postInstall = lib.optionalString withUI ''
     27     install -Dm755 googletranslateui.py $out/bin/googletranslateui
     28     install -Dm644 google_translate.png -t $out/share/gt4gd
     29   '';
     30 
     31   meta = {
     32     description = "Add Google translate to GoldenDict";
     33     homepage = "https://github.com/xinebf/google-translate-for-goldendict";
     34     license = lib.licenses.gpl3;
     35     maintainers = [ lib.maintainers.sikmir ];
     36   };
     37 }