nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

bin.nix (1762B)

      1 { lib
      2 , stdenv
      3 , fetchurl
      4 , fetchgit
      5 , fetchgdrive
      6 , unzip
      7 , wine
      8 , makeWrapper
      9 , withMaps ? true
     10 , withExtremum ? true
     11 }:
     12 let
     13   maps = fetchgit {
     14     url = "http://parasite.kicks-ass.org:3000/sasgis/maps.git";
     15     rev = "950e1b8a02ae7ac84a6ba55e93b57d63cd064688";
     16     sha256 = "sha256-Zz9//kVxqrNhDvgq3YNDRwRUd+mebFgVcXsSmEx1KzQ=";
     17   };
     18   extremum = fetchgdrive {
     19     id = "12PM_mEE8Xck036vXd5TAzPsUZeCnztJ5";
     20     sha256 = "1fx07haxwfz5x8kmw44aswjvf5d0sfgmi9lvycnnc405q4z7i4g9";
     21     name = "Extremum.zip";
     22   };
     23 in
     24 stdenv.mkDerivation rec {
     25   pname = "sasplanet-bin";
     26   version = "201212";
     27 
     28   src = fetchurl {
     29     url = "http://www.sasgis.org/programs/sasplanet/SASPlanet_${version}.zip";
     30     sha256 = "0a6xg75fj4ap0yc3z8sk0vf09dpj75jrkl7v97i2ycy6dim66wi0";
     31   };
     32 
     33   nativeBuildInputs = [ unzip makeWrapper ];
     34 
     35   installPhase = ''
     36     mkdir -p $out/opt/sasplanet
     37     cp -r . $out/opt/sasplanet
     38 
     39     makeWrapper ${wine}/bin/wine $out/bin/sasplanet \
     40       --run "[ -d \$HOME/.sasplanet ] || { cp -r $out/opt/sasplanet \$HOME/.sasplanet && chmod -R +w \$HOME/.sasplanet; }" \
     41       --add-flags "\$HOME/.sasplanet/SASPlanet.exe"
     42   '' + lib.optionalString withMaps ''
     43     cp -r ${maps}/* $out/opt/sasplanet/Maps/sas.maps
     44   '' + lib.optionalString withExtremum ''
     45     unzip ${extremum} -d $out/opt/sasplanet/Maps/sas.maps
     46   '';
     47 
     48   preferLocalBuild = true;
     49 
     50   meta = with lib; {
     51     description = "SAS.Planet is a program designed for viewing and downloading high-resolution satellite imagery and conventional maps";
     52     homepage = "http://www.sasgis.org/sasplaneta/";
     53     changelog = "http://www.sasgis.org/mantis/changelog_page.php";
     54     license = licenses.gpl3Plus;
     55     maintainers = [ maintainers.sikmir ];
     56     platforms = platforms.all;
     57     skip.ci = true;
     58   };
     59 }