nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

package.nix (1570B)

      1 {
      2   lib,
      3   stdenv,
      4   fetchFromGitHub,
      5   fetchpatch,
      6   autoreconfHook,
      7   makeWrapper,
      8   pkg-config,
      9   cairo,
     10   librsvg,
     11   testers,
     12 }:
     13 
     14 stdenv.mkDerivation (finalAttrs: {
     15   pname = "smrender";
     16   version = "4.5.0";
     17 
     18   src = fetchFromGitHub {
     19     owner = "rahra";
     20     repo = "smrender";
     21     tag = "v${finalAttrs.version}";
     22     hash = "sha256-iQSOYiRf4A6HqNmW4oWXIsGIaSHuSvE9wuIiE7JUI8w=";
     23   };
     24 
     25   patches = [
     26     (fetchpatch {
     27       url = "https://github.com/rahra/smrender/commit/bdd7c69e685ef585022fac94ef75d0d7747b042d.patch";
     28       hash = "sha256-zj9gMgmcYHfhRt8HV7BjL9qC+XwtlwUzxrD6MO3lWDg=";
     29     })
     30   ];
     31 
     32   nativeBuildInputs = [
     33     autoreconfHook
     34     makeWrapper
     35     pkg-config
     36   ];
     37 
     38   buildInputs = [
     39     cairo
     40     librsvg
     41   ];
     42 
     43   configureFlags = [
     44     (lib.enableFeature true "threads")
     45     (lib.withFeature true "cairo")
     46     (lib.withFeature true "fontconfig")
     47     (lib.withFeature true "libjpeg")
     48     (lib.withFeature true "librsvg")
     49   ];
     50 
     51   enableParallelBuilding = true;
     52 
     53   postInstall = ''
     54     wrapProgram $out/bin/smrender \
     55       --prefix DYLD_LIBRARY_PATH : $out/lib/smrender \
     56       --prefix LD_LIBRARY_PATH : $out/lib/smrender
     57   '';
     58 
     59   passthru.tests.version = testers.testVersion {
     60     package = finalAttrs.finalPackage;
     61     version = "V${finalAttrs.version}";
     62   };
     63 
     64   meta = {
     65     description = "A powerful, flexible, and modular rule-based rendering engine for OSM data";
     66     homepage = "https://github.com/rahra/smrender";
     67     license = lib.licenses.gpl3Only;
     68     maintainers = [ lib.maintainers.sikmir ];
     69     platforms = lib.platforms.unix;
     70   };
     71 })