nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

package.nix (1121B)

      1 {
      2   lib,
      3   stdenv,
      4   fetchFromGitea,
      5   cmake,
      6   pkg-config,
      7   makeWrapper,
      8   SDL2,
      9   the-foundation,
     10   libX11,
     11 }:
     12 
     13 stdenv.mkDerivation (finalAttrs: {
     14   pname = "bwh";
     15   version = "1.0.3";
     16 
     17   src = fetchFromGitea {
     18     domain = "git.skyjake.fi";
     19     owner = "skyjake";
     20     repo = "bwh";
     21     tag = "v${finalAttrs.version}";
     22     hash = "sha256-POKjvUGFS3urc1aqOvfCAApUnRxoZhU725eYRAS4Z2w=";
     23   };
     24 
     25   nativeBuildInputs = [
     26     cmake
     27     pkg-config
     28     makeWrapper
     29   ];
     30 
     31   buildInputs = [
     32     SDL2
     33     the-foundation
     34   ]
     35   ++ lib.optional stdenv.isLinux libX11;
     36 
     37   installPhase = lib.optionalString stdenv.isDarwin ''
     38     runHook preInstall
     39     mkdir -p $out/Applications
     40     mv *.app $out/Applications
     41     makeWrapper $out/{Applications/Bitwise\ Harmony.app/Contents/MacOS/Bitwise\ Harmony,bin/bitwise-harmony}
     42     runHook postInstall
     43   '';
     44 
     45   meta = {
     46     description = "Bitwise Harmony - simple synth tracker";
     47     homepage = "https://git.skyjake.fi/skyjake/bwh";
     48     license = lib.licenses.bsd2;
     49     maintainers = [ lib.maintainers.sikmir ];
     50     platforms = lib.platforms.unix;
     51     mainProgram = "bitwise-harmony";
     52   };
     53 })