nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

default.nix (2139B)

      1 { lib, stdenv, fetchurl, appimageTools, undmg }:
      2 let
      3   pname = "librewolf";
      4   version = "94.0.2";
      5 
      6   srcs = {
      7     x86_64-linux = fetchurl {
      8       url = "https://gitlab.com/api/v4/projects/24386000/packages/generic/librewolf/${version}-2/LibreWolf.x86_64.AppImage";
      9       hash = "sha256-ciD0kOVt3mwckuXQwX+wrXyIsxy1cki6S58W8aBABDw=";
     10     };
     11     aarch64-linux = fetchurl {
     12       url = "https://gitlab.com/api/v4/projects/24386000/packages/generic/librewolf/${version}-2/LibreWolf.aarch64.AppImage";
     13       hash = "sha256-03/JuyoqxuweQ6RsQ59QUG0uKogA+OT1WBgHeR/VBrg=";
     14     };
     15     x86_64-darwin = fetchurl {
     16       url = "https://gitlab.com/librewolf-community/browser/macos/uploads/af4732e68ec6219135288af9fffdd920/librewolf-${version}-1.dmg";
     17       hash = "sha256-gTlQKHgcGlm/YNXmG5YMrfcwKC+P5Wc0Dmj4rqvguD8=";
     18     };
     19     aarch64-darwin = fetchurl {
     20       url = "https://gitlab.com/librewolf-community/browser/macos/uploads/28eb3a54b3a320cdb09773e848e681d2/librewolf-${version}-1_aarch64_exp.dmg";
     21       hash = "sha256-iDHS4UODdQWXxHfiyVJi1AO8JbFe0fKrQjryjz4339M=";
     22     };
     23   };
     24   src = srcs.${stdenv.hostPlatform.system};
     25 
     26   meta = with lib; {
     27     description = "A fork of Firefox, focused on privacy, security and freedom";
     28     homepage = "https://librewolf-community.gitlab.io/";
     29     license = licenses.mpl20;
     30     maintainers = [ maintainers.sikmir ];
     31     platforms = builtins.attrNames srcs;
     32     skip.ci = true;
     33   };
     34 
     35   appimageContents = appimageTools.extract {
     36     inherit pname version src;
     37   };
     38 
     39   linux = appimageTools.wrapType2 rec {
     40     inherit pname version src meta;
     41 
     42     extraInstallCommands = ''
     43       mv $out/bin/{${pname}-${version},${pname}}
     44       install -Dm644 ${appimageContents}/io.gitlab.LibreWolf.desktop -t $out/share/applications
     45       install -Dm644 ${appimageContents}/librewolf.png -t $out/share/icons/hicolor/256x256/apps
     46     '';
     47   };
     48 
     49   darwin = stdenv.mkDerivation {
     50     inherit pname version src meta;
     51 
     52     nativeBuildInputs = [ undmg ];
     53 
     54     sourceRoot = ".";
     55 
     56     installPhase = ''
     57       mkdir -p $out/Applications
     58       cp -r *.app $out/Applications
     59     '';
     60   };
     61 in
     62 if stdenv.isDarwin
     63 then darwin
     64 else linux