nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

package.nix (1599B)

      1 {
      2   lib,
      3   stdenv,
      4   fetchFromGitHub,
      5   fetchpatch,
      6   autoreconfHook,
      7   makeWrapper,
      8   pkg-config,
      9   cairo,
     10   librsvg,
     11   testers,
     12 }:
     13 
     14 stdenv.mkDerivation (finalAttrs: {
     15   pname = "smrender";
     16   version = "4.5.0";
     17 
     18   __structuredAttrs = true;
     19 
     20   src = fetchFromGitHub {
     21     owner = "rahra";
     22     repo = "smrender";
     23     tag = "v${finalAttrs.version}";
     24     hash = "sha256-iQSOYiRf4A6HqNmW4oWXIsGIaSHuSvE9wuIiE7JUI8w=";
     25   };
     26 
     27   patches = [
     28     (fetchpatch {
     29       url = "https://github.com/rahra/smrender/commit/bdd7c69e685ef585022fac94ef75d0d7747b042d.patch";
     30       hash = "sha256-zj9gMgmcYHfhRt8HV7BjL9qC+XwtlwUzxrD6MO3lWDg=";
     31     })
     32   ];
     33 
     34   nativeBuildInputs = [
     35     autoreconfHook
     36     makeWrapper
     37     pkg-config
     38   ];
     39 
     40   buildInputs = [
     41     cairo
     42     librsvg
     43   ];
     44 
     45   configureFlags = [
     46     (lib.enableFeature true "threads")
     47     (lib.withFeature true "cairo")
     48     (lib.withFeature true "fontconfig")
     49     (lib.withFeature true "libjpeg")
     50     (lib.withFeature true "librsvg")
     51   ];
     52 
     53   enableParallelBuilding = true;
     54 
     55   postInstall = ''
     56     wrapProgram $out/bin/smrender \
     57       --prefix DYLD_LIBRARY_PATH : $out/lib/smrender \
     58       --prefix LD_LIBRARY_PATH : $out/lib/smrender
     59   '';
     60 
     61   passthru.tests.version = testers.testVersion {
     62     package = finalAttrs.finalPackage;
     63     version = "V${finalAttrs.version}";
     64   };
     65 
     66   meta = {
     67     description = "A powerful, flexible, and modular rule-based rendering engine for OSM data";
     68     homepage = "https://github.com/rahra/smrender";
     69     license = lib.licenses.gpl3Only;
     70     maintainers = [ lib.maintainers.sikmir ];
     71     platforms = lib.platforms.unix;
     72   };
     73 })