nur-packages

My NUR packages
git clone git://git.sikmir.ru/nur-packages
Log | Files | Refs | README | LICENSE

package.nix (1137B)

      1 {
      2   lib,
      3   stdenv,
      4   fetchsvn,
      5 }:
      6 
      7 stdenv.mkDerivation {
      8   pname = "ocad2mp";
      9   version = "1.14-unstable-2011-01-26";
     10 
     11   __structuredAttrs = true;
     12 
     13   src = fetchsvn {
     14     url = "svn://svn.code.sf.net/p/ocad2mp/code/trunk/ocad2mp";
     15     rev = "269";
     16     sha256 = "sha256-w5QV7dwfTAWRJ3ausSIRHbR8ZiUp761lwkc0qd1VAJw=";
     17   };
     18 
     19   postPatch = lib.optionalString stdenv.isDarwin ''
     20     substituteInPlace Makefile.gcc \
     21       --replace-fail "CXX=g++" "" \
     22       --replace-fail "LINK=g++" "LINK=$CXX" \
     23       --replace-fail "-lgcc" ""
     24   '';
     25 
     26   env.NIX_CFLAGS_COMPILE = toString [
     27     "-std=c++03"
     28     "-include stddef.h"
     29   ];
     30 
     31   makeFlags = [
     32     "-f"
     33     "Makefile.gcc"
     34     "CFG=Release"
     35     "TARGET_ARCH_BITS=64"
     36   ];
     37 
     38   hardeningDisable = [ "format" ];
     39 
     40   installPhase = ''
     41     install -Dm755 Release/ocad2mp -t $out/bin
     42     install -Dm644 SYM.TXT $out/share/ocad2mp/sym.txt
     43   '';
     44 
     45   meta = {
     46     description = "Converter from OCAD map format to Polish format";
     47     homepage = "https://sourceforge.net/projects/ocad2mp/";
     48     license = lib.licenses.gpl2;
     49     maintainers = [ lib.maintainers.sikmir ];
     50     platforms = lib.platforms.unix;
     51   };
     52 }